***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 16, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3432   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		   w = 1e-6			level = 3
+  vto = 0.92			  kp = 5.2			   rb = 1.843e-2)
.model  dds   d(
+   is = 3.105e-12	   n = 1.103		   rs = 1.509e-1
+   eg = 1.180		trs1 = 2.269e-3)
.model  dbody d(
+   is = 3.105e-12	   n = 1.103		   rs = 1.509e-1
+   eg = 1.180		trs1 = 2.269e-3
+  cjo = 3.232e-11	   m = 2.055e-1		   vj = 2.206e-1
+   bv = 33			 ibv = 250e-6		 tbv1 = 5.724e-4			tt = 25n)
.model  inter  nmos(
+  vto = 0			  kp = 10			level = 1)
.model  dgd    d(
+  cjo = 4.719e-11	   m = 5.216e-1		   vj = 2.552e-1)
.param
+  cgs = 1.342e-10	 cgd = 4.706e-11
+   rd = 3.060e-2		  ra = 3.521e-2		 trd1 = 9.821e-3
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ic = 0
egv	  2t  3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (1.75 , 1.75 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.50 ),
+ (3.00 , 2.80 ),
+ (3.50 , 3.00 ),
+ (4.00 , 3.20 ),
+ (4.50 , 3.32 ),
+ (6.00 , 3.55 ),
+ (8.00 , 3.70 ))   
+ (10.0 , 3.70 ))
egt	  1  2t   value = {7.354e-4*limit(v(2t,3),0,1.0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}	tc={trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
